A.C.E. 3/ACE CD 3.iso/files/utils/fcalc11.dms/fcalc11.adf/Install-FinalCalc

Text File | 1995-08-30 | 10KB | 454 lines

; FinalCalc Installer script
; Copyright © 1995 Khalid Aldoseri
;
; $VER: Install-FinalCalc 0.7 (25 Aug 1995)
;


; Find out if the user has an FPU installed and set the default version
; of FinalCalc to install.

(set defaultversion 2)

(set fputest
    (run "c:cpu >NIL: check fpu")
)

(if fputest
    (set defaultversion 1)
)


; Ask user where to install the program

(set FinalCalc_dest
    (tackon
        (askdir
            (prompt "In which disk or drawer should FinalCalc should be installed?  "
                    " (a directory named FinalCalc will be created for you)"
            )
            (help @askdir-help)
            (default @default-dest)
        )
        "FinalCalc"
    )
)

; make drawer & icon if not there

(makedir FinalCalc_dest (infos))
(complete 1)

; make sub-directories if not there

(makedir (tackon FinalCalc_dest "Config"))
(complete 2)
(makedir (tackon FinalCalc_dest "Fonts"))
(complete 3)
(makedir (tackon FinalCalc_dest "Guide"))
(complete 4)
(makedir (tackon FinalCalc_dest "Libs"))
(complete 5)
(makedir (tackon FinalCalc_dest "PanelIcons") (infos))
(complete 6)
(makedir (tackon FinalCalc_dest "Projects") (infos))
(complete 7)
(makedir (tackon FinalCalc_dest "Rexx"))
(complete 8)
(makedir "ENVARC:FinalCalc")
(complete 9)

(set @default-dest FinalCalc_dest)
(complete 10)


; Copy the extraction utility over and remember where it is

(copyfiles
    (source "FinalCalc Disk 1:lhex")
    (dest FinalCalc_dest)
)

(set lhex (tackon FinalCalc_dest "lhex"))

(complete 15)


; Ask user to select which version of program to install

(set install_versions
    (askoptions
        (prompt "What version of FinalCalc would you like to install?\n(The correct version for your system is already selected.  For more information, click on the Help button.)")
        (choices
            " FinalCalc Normal Version  (927k)"
            " FinalCalc FPU Version     (875k)"
            )
        (help    "The FinalCalc Normal Version runs on all Amiga systems.\n\n"
                "The FPU Version runs only on Amiga systems with a 68020, "
                "68030, 68040 or 68060 processor and a floating point processor unit (FPU).  "
                "It is faster and smaller than the Normal version."
             )
        (default defaultversion)
    )
)



(set install_options
    (askoptions
        (prompt "The install script will copy the following objects to your hard disk:")
        (choices
            " Program Libraries      (233k)"
            " Program Icons          (  7k)"
            " Online Help Guide      (447k)"
            " Default Configuration  (  4k)"
            " Default Outline Fonts  (191k)"
            " Demo Projects          (120k)"
            " Demo Scripts           (  7k)"
            " Emergency Recoverer    ( 16k)"
            )
        (help    "FinalCalc does not need these objects to operate, but not installing them "
                "(except for the demo projects and scripts) will affect its functionality.\n\n"
                "It is highly recommended that you install them all unless you have very limited "
                "hard disk space.\n\n"
                "The Emergency Recoverer is a program that can recover your projects "
                "from system memory after a crash."
             )
        (default 255)
    )
)


; Ask user to select outline fonts to install

(set install_fonts
    (askoptions
        (prompt "Please select the outline fonts to install")
        (choices
            " Basic Outline Font Set      (  855k)"
            " Extended Oultine Fonts Set  (1,840k)"
            )
        (help    "The basic outline font set contains outline fonts that FinalCalc"
                " will normally require during printing.  You may, however, opt"
                " not to install them to save space on your hard disk.\n\n"

                "The extended set contains a lot more outline fonts that you"
                " may wish to install if you have a lot of extra hard disk space."
             )
        (default 3)
    )
)


; Make installer cd into FinalCalc_dest when it executes the run statement
(set @execute-dir FinalCalc_dest)

; If the user selected the Normal version, copy it over

(set error 0)

(if (IN install_versions 0)
    (    (working "Installing FinalCalc program from Disk 1.")
        (set error
            (run
                ("\"%s\" -f x \"FinalCalc Disk 1:FC.lha\" >NIL:" lhex)
            )
        )

        (if error
            (abort ("Error installing FinalCalc:\n\n  Cannot find or read FC.lha file\n from Disk 1."))
        )
    )
)

(complete 25)


(set @execute-dir (tackon FinalCalc_dest "Projects"))

(if (IN install_options 5)
((working "Installing demo projects from Disk 1.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 1:FCprojects.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCprojects.lha file\n from Disk 1."))
    )
)
)

(complete 30)

; If the user selected the FPU version, copy it over

(set error 0)

(set @execute-dir FinalCalc_dest)

(if (IN install_versions 1)
    (    (working "Installing FinalCalc.FPU program from Disk 2.")
        (set error
            (run
                ("\"%s\" -f x \"FinalCalc Disk 2:FCfpu.lha\" >NIL:" lhex)
            )
        )

        (if error
            (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCfpu.lha file\n from Disk 2."))
        )
    )
)


(complete 40)

(set @execute-dir (tackon FinalCalc_dest "Libs"))

(if (IN install_options 0)
((working "Installing program libraries from Disk 2.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 2:FClibs.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FClibs.lha file\n from Disk 2."))
    )

(working "Testing libraries installed in your system.")

    (if (exists "libs:kd_freq.library")
        (
            (set error
                (run "version >NIL: libs:kd_freq.library version 5 revision 1"))

            (if error
                (if    (askbool (
                    (help @askbool-help)
                    (prompt "You currently have an older version of kd_freq.library "
                        "installed in your LIBS: directory.  Would you like to "
                        "update it?")))

                    (copyfiles
                        (source (tackon FinalCalc_dest "Libs/kd_freq.library"))
                        (dest "Libs:")
                    )
                )
            )
        )
    )
)
)

(complete 45)



(set @execute-dir (tackon FinalCalc_dest "PanelIcons"))

(if (IN install_options 1)
((working "Installing program icons from Disk 2.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 2:FCicons.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCicons.lha file\n from Disk 2."))
    )
)
)

(complete 50)


(set @execute-dir (tackon FinalCalc_dest "Guide"))

(if (IN install_options 2)
((working "Installing online help guide from Disk 2.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 2:FCguide.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCguide.lha file\n from Disk 2."))
    )
)
)


(complete 60)


(set @execute-dir (tackon FinalCalc_dest "Rexx"))

(if (IN install_options 6)
((working "Installing demo scripts from Disk 2.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 2:FCrexx.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCrexx.lha file\n from Disk 2."))
    )
)
)

(complete 62)


(set @execute-dir FinalCalc_dest)

(if (IN install_options 3)
((working "Installing other files from Disk 2.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 2:FCmisc.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCmisc.lha file\n from Disk 2."))
    )
)
)
(complete 63)


(set @execute-dir "ENVARC:FinalCalc")

(if (IN install_options 3)
((working "Installing default ENVARC settings from Disk 2.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 2:FCenv.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCenv.lha file\n from Disk 2."))
    )
)
)
(complete 65)


(set @execute-dir FinalCalc_dest)

(if (IN install_options 7)
((working "Installing Recoverer from Disk 2.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 2:FCrecoverer.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCrecoverer.lha file\n from Disk 2."))
    )
)
)
(complete 66)


(set @execute-dir (tackon FinalCalc_dest "Fonts"))

(if (IN install_options 4)
((working "Installing default outline fonts from Disk 2.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 2:FCdeffont.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCdeffont.lha file\n from Disk 2."))
    )
)
)
(complete 70)



(set @execute-dir (tackon FinalCalc_dest "Fonts"))


(if (IN install_fonts 0)
((working "Installing basic outline fonts from Disk 3.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 3:FCfonts.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCfonts.lha file\n from Disk 3."))
    )
)
)

(complete 80)


(if (IN install_fonts 1)
((working "Installing extended outline fonts from Disk 3.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 3:FCfonts2.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCfonts2.lha file\n from Disk 3."))
    )
)
)

(complete 85)

(if (IN install_fonts 1)
((working "Installing extended outline fonts from Disk 4.")
    (set error
        (run
            ("\"%s\" -f x \"FinalCalc Disk 4:FCfonts3.lha\" >NIL:" lhex)
        )
    )

    (if error
        (abort ("Error installing FinalCalc:\n\n  Cannot find or read FCfonts3.lha file\n from Disk 4."))
    )
)
)


(complete 99)

; modify S:User-Startup

(startup "FinalCalc"
    (prompt
        "Some instructions need to be added to the \"S:user-startup\" "
        "file so that your system will be properly configured to use FinalCalc.")
    (help "Do this or FinalCalc won't work correctly!!")
    (command "ASSIGN FinalCalc: \"" FinalCalc_dest "\"\n")
)


; Set up the assign for immediate use

(makeassign "FinalCalc" FinalCalc_dest)


(delete lhex)
(complete 100)
(exit)